Archivos Assembling (ASM)

[albertnet3]

el source de mi ultimo parchesito

include "x.inc"

DataBrowserDesc_SetViewModeAndSortOrder equ 0x1428C434
DataBrowserDesc_SetItemStyle             equ 0x1416AE70
GUIObject_SoftKeys_SetAction             equ 0x1417EFA0
GUIObject_SoftKeys_SetText                 equ 0x141C8864
GUIObject_SoftKeys_SetVisible             equ 0x141C85C8
openfolderSound                         equ 0x154D0188
;W705 SW-R1GA031
;Enable Progress Bar in sound recording.
;remove system sound of memory full in sound recording.
;add option view and sort order in "Recorded sounds".
;add the option "Recorded sounds"
;in the first gui of  Sound Recorder book.
;(c) albertnet3
;V1.0 Fix

org 0x14EA0500;Enable Progress Bar in sound recording
MOV     R1, 0

;remove system sound of memory full in sound recording
org 0x14D326BE
nop
nop

;remove system sound of memory full in sound recording
org 0x14D326FA
nop
nop

;add the option "Recorded sounds"
;in the first gui of  Sound Recorder book.
org 0x154CFCB2    
ldr r3,_newitem2
blx r3

org 0x154CFCF0    
_newitem2 dw newitem2+1

;add option view and short order in record sound
org 0x154D01B6        
ldr r1,_newitem
bx r1
align 4
_newitem dw newitem+1
nop
_return:

org 0x15CF4FB0
newitem:
CMP     R0, 0
BEQ     myret
MOV     R1, 0x8
ADD     R0, R5, 0
BL      _DataBrowserDesc_SetViewModeAndSortOrder
MOV     R1, 0xc
ADD     R0, R5, 0
BL      _DataBrowserDesc_SetItemStyle
myret:
LDR     R3, off_return
BX      R3 
;------------------------------
newitem2:
LDR     R2, RECORD_LNG
LDR     R0, [R4,0x1C]
PUSH    {R0-R3,LR}
LDR     R2, SKACTIONPROC
MOV        R1, 0 
LDR     R0, [R4,0x1C]
LDR     R3, off_GUIObject_SoftKeys_SetAction
BLX     R3
movl     R2, 0x1F20
add     R2, 1
MOV        R1, 0
LDR     R0, [R4,0x1C]
LDR     R3, off_GUIObject_SoftKeys_SetText
BLX     R3
MOV     R2, 1
MOV     R1, 0
LDR     R0, [R4,0x1C]
LDR     R3, off_GUIObject_SoftKeys_SetVisible
BLX     R3
POP     {R0-R3,PC}
    
align 4
_DataBrowserDesc_SetViewModeAndSortOrder:
LDR     R3, off_DataBrowserDesc_SetViewModeAndSortOrder
BX      R3 

_DataBrowserDesc_SetItemStyle:
LDR     R3, off_DataBrowserDesc_SetItemStyle
BX      R3 

RECORD_LNG dw 0x1F1F
SKACTIONPROC dw openfolderSound+1
off_GUIObject_SoftKeys_SetAction  dw  GUIObject_SoftKeys_SetAction+1
off_GUIObject_SoftKeys_SetText    dw GUIObject_SoftKeys_SetText+1
off_GUIObject_SoftKeys_SetVisible dw GUIObject_SoftKeys_SetVisible+1
off_DataBrowserDesc_SetViewModeAndSortOrder dw DataBrowserDesc_SetViewModeAndSortOrder+1
off_DataBrowserDesc_SetItemStyle dw DataBrowserDesc_SetItemStyle+1
align 4
off_return dw _return+1