Archivos Assembling (ASM)

[DaRkMaN]

Les dejo el asm de un parche que acabo de editar

• Offsets: W595 R3EF001

include "x.inc"
include "W595_R3EF001.lib.asm"


;W595 SW-R3EF001
;Añade un nuevo elemento en el menu "Iniciar telefono"
;(i) Necesita el parche "Trabaja el radio en modo de vuelo"
;(c) Tartes
;(e) jamesbond22
;(e) albertnet3
;Cambia el estilo GUI de los elementos
;Añade:
;+calendario
;+Grabadora
;+camara
;(e,p) DaRkMaN
;Añadido:
;+Admin de archivos
;+Calculadora
;+Cronometro


org 0x11A5A42A 
_StyleItems:
                       MOV     R1, 2
                       
org 0x11A5A43C 
_numero_de_items:
                       MOV     R1, 9
                       
org 0x11A5A3EE 
_apatch2X:
                       LDR     R4, apatch2
                       BX      R4
align 4
apatch2    dw patch2+1

org 0x11A5A516 
_abodyX:
                       LDR     R0, abody
                       BX      R0
align 4
abody    dw body+1      

org 0x127A0CA0 
body:
        ADD    R0, R4,    0
        BL    aGUIonMessage_GetCreatedItemIndexX
;============== Lista Items========================
        CMP    R0, 0
        BEQ    normal_mode
        CMP    R0, 1
        BEQ    fligth_mode
        CMP    R0, 2
        BEQ    filemanager
        CMP    R0, 3
        BEQ    calculadora
        CMP    R0, 4
        BEQ    cronometro
        CMP    R0, 5
        BEQ     calendario
        CMP    R0, 6
        BEQ    grabadora
        CMP    R0, 7
        BEQ    camara
        CMP    R0, 8
        BEQ    radio 
        B    return1
;=======================================================
normal_mode:                
        ADD    R1, R7,    3
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        ADD    R1, R7,    2
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, normalmode_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX
        B    return2
;=======================================================
fligth_mode:                
        ADD    R1, R7,    1
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        ADD    R1, R7,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, flightmode_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX
        B    return2
;=======================================================
radio:                
        LDR    R1, Radio_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        LDR    R1, FM_radio_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, Radio_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX
        B    return2
;=======================================================
filemanager:                
        LDR    R1, filemanager_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        LDR    R1, filemanager1_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, filemanager_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX
        B    return2
;=======================================================
calculadora:                
        LDR    R1, calculadora_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        LDR    R1, calculadora1_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, calculadora_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX
        B    return2
;=======================================================
cronometro:                
        LDR    R1, cronometro_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        LDR    R1, cronometro1_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, cronometro_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX
        B    return2
;=======================================================
calendario:                
        LDR    R1, calendario_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        LDR    R1, calendario1_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, calendario_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX    
        B    return2
;=======================================================        
camara:                
        LDR    R1, camara_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        LDR    R1, camara1_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, camara_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX    
        B    return2
;=======================================================
grabadora:                
        LDR    R1, grabadora_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemTextX
        LDR    R1, grabadora1_lng
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemInfoTextX
        LDR    R2, grabadora_icn
        ADD    R1, R6,    0
        ADD    R0, R4,    0
        BL    link_GUIonMessage_SetMenuItemIconX        
;=======================================================
return2:                                
        MOV    R6, 1
;=======================================================
return1:                
        ADD    R0, R6,    0
        POP    {R4-R7,PC}
;============patch2=============================
patch2:        
        ADD    R4, R0,    0
        LDR    R0, [R0,0x20]
        BL    aListMenu_GetSelectedItemX
        CMP    R0, 0
        BEQ    normal_modeX
        CMP    R0, 1
        BEQ    fligth_modeX
        CMP    R0, 2
        BEQ    filemanagerX
        CMP    R0, 3
        BEQ    calculadoraX
        CMP    R0, 4
        BEQ    cronometroX
        CMP    R0, 5
        BEQ    calendarioX
        CMP    R0, 6
        BEQ    grabadoraX
        CMP    R0, 7
        BEQ    camaraX 
        CMP    R0, 8
        BEQ    radioX
        B    return1end2
;=======================================================
normal_modeX:                
        MOV    R0, 0
        B    flight_mode_off
;=======================================================
fligth_modeX:                
        MOV    R0, 1
;=======================================================
flight_mode_off:                
        BL    flight_mode_offX
        B    return1end2
;=======================================================
grabadoraX:                
        BL    aSoundRecorder_RecordCallX
        POP    {R0,PC}
;=======================================================      
filemanagerX:
        LDR    R0, afilemanager
        B    run_pague
;=======================================================    
calculadoraX:
        LDR    R0, acalculadora
        B    run_pague
;=======================================================  
cronometroX:
        LDR    R0, acronometro
        B    run_pague
;=======================================================  
calendarioX:
        LDR    R0, acalendario
        B    run_pague
;=======================================================        
camaraX:
        LDR    R0, acamara
        B    run_pague    
;=======================================================
radioX:    
        LDR    R0, aFmradio
run_pague:        
        BL    aShortcut_RunX
        POP    {R4,PC}
;=======================================================
return1end2:                                    
        LDR    R1, areturn1end2
        BX    R1
;=======================================================
link_GUIonMessage_SetMenuItemTextX:                
        LDR    R3, link_GUIonMessage_SetMenuItemText
        BX    R3
;=======================================================
link_GUIonMessage_SetMenuItemInfoTextX:                
        LDR    R3, link_GUIonMessage_SetMenuItemInfoText
        BX    R3
;=======================================================
link_GUIonMessage_SetMenuItemIconX:                        
        LDR    R3, link_GUIonMessage_SetMenuItemIcon
        BX    R3
;=======================================================
aGUIonMessage_GetCreatedItemIndexX:                
        LDR    R3, aGUIonMessage_GetCreatedItemIndex
        BX    R3        
;=======================================================
aListMenu_GetSelectedItemX:                
        LDR    R3, aListMenu_GetSelectedItem
        BX    R3        
;=======================================================
flight_mode_offX:                
var_18        = -0x18
var_14        = -0x14
        LDR    R3, aflight_mode_off
        BX    R3
;=======================================================
aShortcut_RunX:                
        LDR    R3, aShortcut_Run
        BX    R3    
;=======================================================        
aSoundRecorder_RecordCallX:                
var_214        = -0x214
var_210        = -0x210
        LDR    R3, aSoundRecorder_RecordCall
        BX    R3                    
;====================icons===================================
        align 4
normalmode_icn                            dw 0xEB66         
flightmode_icn                            dw 0xEB65             
Radio_icn                                dw 0xEB42     
filemanager_icn                          dw 0xEA97
calculadora_icn                          dw 0xE58C
cronometro_icn                          dw 0xF4E6
calendario_icn                            dw 0xEABC 
grabadora_icn                            dw 0xF49E 
camara_icn                                dw 0xEA88 
;====================labels===================================        
Radio_lng                                dw 0xB8F         
FM_radio_lng                            dw 0x2322    
filemanager_lng                        dw 0x674
filemanager1_lng                        dw 0x6B8
calculadora_lng                        dw 0x1300
calculadora1_lng                        dw 0x12FF
cronometro_lng                        dw 0x13F1
cronometro1_lng                        dw 0x254A
calendario_lng                            dw 0x11AB 
calendario1_lng                            dw 0x1301 
grabadora_lng                            dw 0x26A7 
grabadora1_lng                            dw 0x1428 
camara_lng                                dw 0x2B5 
camara1_lng                                dw 0x587 
;====================funtions and branchs===================================
link_GUIonMessage_SetMenuItemText                dw GUIonMessage_SetMenuItemText        
link_GUIonMessage_SetMenuItemInfoText            dw GUIonMessage_SetMenuItemInfoText        
link_GUIonMessage_SetMenuItemIcon                dw GUIonMessage_SetMenuItemIcon    
aGUIonMessage_GetCreatedItemIndex                dw GUIonMessage_GetCreatedItemIndex                 
aListMenu_GetSelectedItem                        dw ListMenu_GetSelectedItem                     
areturn1end2                                    dw 0x11A5A40A+1       
aflight_mode_off                                dw 0x11A5A2C0+1 
aFmradio                                        dw 0x11B6293C ;FM Radio    
acalendario                                        dw 0x11B82EB0 ;Menu_CalendarMain  
acamara                                            dw 0x11B83C7C ;Camera
afilemanager                                       dw 0x11B7FE94 ;FileManager
acalculadora                                       dw 0x11B80D10 ;Calculator
acronometro                                        dw 0x11B82F50 ;Cronometro
aSoundRecorder_RecordCall                        dw SoundRecorder_RecordCall    
aShortcut_Run                                    dw Shortcut_Run
;=======================================================

Saludos ..