Archivos Assembling (ASM)

[anarkes]

Este es el ASM de mi parche, espero y les sea de ayuda a los que deseen aprender

;W580 SW-R8BE001
;Add the number of latest recent contacts (without options) when sending SMS in Second line of title
;Added the hability to choose the items with keys
;(!) You can modify the GUI options in the end of patch
;© anarkes
;v 1.1

include "x.inc"
include "./lib/W580_R8BE001.asm"

org 0x4503F2AC ;New_Hook
    LDR R2, hook_0
    BX    R2

    NOP

align 4
hook_0    DCD newcode+1

next:

org 0x45DACDA0
newcode:

    LSL     R1, R5, 0x10
    LSR     R7, R1, 0x10 ;Counter is alocate in R7
    CMP     R0, 0
    BEQ     salto_0
    LDR     R1, [SP,4] ;Title
    BL    GUIObject_SetTitleText_0
    LDR  R0, [R4,0x40] ;GUI
    MOV     R1, 5 ;Type
    BL     GUIObject_SetTitleType_0
    ADD     R0, R7, 0 ;Num of item
    BL     int2strID_0
    LSL  R1, R5, 0x10
    MOVL    R2,    0x50000
    CMP     R2, R1
    BEQ    Sub_3
    SUB R0, 2
return:
    ADD     R1, R0, 0 ;Text
    LDR  R0, [R4,0x40] ;GUI
    BL     Set2Titles_0
    LDR  R0, [R4,0x40] ;GUI
    MOVL R1, 0xED00 ;Icon Base
    ADD R1, 0xCB ;Icon Complement
    BL     GUIObject_SetTitleIcon_0
    LDR  R0, [R4,0x40] ;GUI
    MOV     R1, 3 ;LKHM_PRESS
    BL     ListMenu_SetHotkeyMode_0
    ADR    R2, settings
    LDRB R2, [R2]
    CMP R2, 1
    BEQ SetFullScreen
    B GetOtherSetting

Sub_3:
    SUB R0, 3
    B return

salto_0:
    LDR    R3, hook_2
    BX    R3

SetFullScreen:
    LDR  R0, [R4,0x40] ;GUI
    MOV     R1, 4 ;FullScreen
    BL     GUIObject_SetStyle_0

GetOtherSetting:
    ADR    R1, settings
    LDRB    R1, [R1,1]
    CMP R1, 1
    BEQ HideSoftkeys
    B RoveBackground

HideSoftkeys:
    LDR  R0, [R4,0x40] ;GUI
    BL     GUIObject_SoftKeys_Hide_0

RoveBackground:
    LDR  R0, [R4,0x40] ;GUI
    BL     GUIObject_SoftKeys_RemoveBackground_0

    LDR     R0, [R4,0x40]
    LDR    R1, next_0
    BX    R1

;Functions
GUIObject_SetTitleText_0:
    LDR    R3, func_0
    BX    R3

GUIObject_SetStyle_0:
    LDR    R3, func_1
    BX    R3

GUIObject_SoftKeys_RemoveBackground_0:
    LDR    R3, func_2
    BX    R3

GUIObject_SoftKeys_Hide_0:
    LDR    R3, func_3
    BX    R3

ListMenu_SetHotkeyMode_0:
    LDR    R3, func_4
    BX    R3

GUIObject_SetTitleType_0:
    LDR    R3, func_5
    BX    R3

Set2Titles_0:
    LDR    R3, func_6
    BX    R3

int2strID_0:
    LDR    R3, func_7
    BX    R3

GUIObject_SetTitleIcon_0:
    LDR    R3, func_8
    BX    R3

align 4
hook_2    DCD 0x4503F33C+1
next_0    DCD next+1
func_0    DCD    GUIObject_SetTitleText+1
func_1    DCD GUIObject_SetStyle+1
func_2    DCD    GUIObject_SoftKeys_RemoveBackground+1
func_3    DCD    GUIObject_SoftKeys_Hide+1
func_4    DCD    ListMenu_SetHotkeyMode+1
func_5    DCD GUIObject_SetTitleType+1
func_6    DCD    0x453653E4+1
func_7    DCD    int2strID+1
func_8    DCD GUIObject_SetTitleIcon+1

settings DCB 1 ;(0 = Normal, 1 = FullScreen)
         DCB 0 ;(0 = Show Softkeys, 1 = Hide Softkeys)